VBScript Sample: vbscript/ado/publishers/publishers.asp

	ASP Script
	Comments or Client-side Script
	HTML and Text
<%@ Language=VBScript %>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>

<%
' Open one connection and create one recordset
if Request.Form("drvtxt").Count <> 0 then
   drv = Request.Form("drvtxt")
   url = Request.Form("urltxt")
   uid = Request.Form("uidtxt")
   pwd = Request.Form("pwdtxt")

    dim DrvArry(15)
    DrvArry(0) = "--Please select a driver--"
    DrvArry(1) = "sun.jdbc.odbc.JdbcOdbcDriver"
    DrvArry(2) = "sun.jdbc.odbc.JdbcOdbcDriver"
    DrvArry(3) = "oracle.jdbc.driver.OracleDriver"
    DrvArry(4) = "com.informix.jdbc.IfxDriver"
    DrvArry(5) = "twz1.jdbc.mysql.jdbcMysqlDriver"
    DrvArry(6) = "org.gjt.mm.mysql.Driver"
    DrvArry(7) = "com.sybase.jdbc2.jdbc.SybDriver"
    DrvArry(8) = "COM.cloudscape.core.JDBCDriver"
    DrvArry(9) = "postgresql.Driver"
    DrvArry(10) = "intersolv.jdbc.sequelink.SequeLinkDriver"
    DrvArry(11) = "intersolv.jdbc.sequelink.SequeLinkDriver"
    DrvArry(12) = "intersolv.jdbc.sequelink.SequeLinkDriver"
    DrvArry(13) = "intersolv.jdbc.sequelink.SequeLinkDriver"
    DrvArry(14) = "intersolv.jdbc.sequelink.SequeLinkDriver"
    DrvArry(15) = "openlink.jdbc2.Driver"

   select case drv
      case 1, 14:
         dbms = "Access"
      case 2, 13, 15:
         dbms = "SQLServer"
      case 3, 10:
         dbms = "Oracle"
      case 4, 11:
         dbms = "Informix"
      case 5, 6:
         dbms = "MySQL"
      case 7, 12:
         dbms = "Sybase"
      case 8:
         dbms = "Cloudscape"
      case 9:
         dbms = "Postgres"
      case else
         dbms = ""
   end select

   strCnn = "Driver=" & DrvArry(drv) & ";URL=" & url & ";UID=" & uid & ";PWD=" & pwd & ";"

   Set conn = Server.CreateObject("ADODB.CONNECTION")
   conn.Open strCnn

   Set Session("PublishRd") = Server.CreateObject("ADODB.RECORDSET")
   Session("PublishRd").Open "Publishers", conn, 1, 2
   movecnt = 1
else
   dbms = Request.QueryString("dbms")
   movecnt = CInt( Request.QueryString("movecnt") )
end if

set RS = Session("PublishRd")

If RS.RecordCount > 0 then
   direction = CInt( Request.QueryString("direction") )

   select case direction
   case 1:
      RS.MoveFirst
      movecnt = 1
   case 2:
      If not RS.BOF Then
         RS.MovePrevious
         movecnt = movecnt - 1
      End If
   case 3:
      If not RS.EOF Then
         RS.MoveNext
         movecnt = movecnt + 1
      End If
   case 4:
      RS.MoveLast
      movecnt = RS.RecordCount
   end select

   ' Error Handling   
   If RS.EOF Then
      movecnt = RS.RecordCount
      RS.MoveLast 
   End If

   If RS.BOF Then
      movecnt = 1
      RS.MoveFirst
   End If
else
   movecnt = 0
End If
%>

<font size="4" face="Arial, Helvetica">
<b>BLOB of LONG VARCHAR Database Sample</b></font><br>
<hr size="1" color="#000000">

<FORM Method=Post Name=form1>
<TABLE width=100%>
   <TR><TD width=60%>
      <TABLE width=100%>
<%      Set fieldInfo = RS.Fields 
      for i = 0 to fieldInfo.Count - 2
         Set field = fieldInfo.Item(i)%>
         <TR><TD align=center width=40%><%=field.Name%>:</TD>
         <TD width=60%>
            <%if RS.Eof or RS.Bof then%>
               <Input Type=Text  name="Text<%=i%>" size=25 >
            <%else%>
               <Input Type=Text  name="Text<%=i%>" size=25 Value="<%=field.Value%>">
            <%end if%>
            </TD></TR>
      <%Next%>
      </TABLE>
      <TD width=5%></TD>
      <TD width=35%>
      <%set field = fieldInfo.Item(9)%>
         <%=field.Name%>:<BR>
         <%if RS.Eof or RS.Bof then%>
            <TextArea Name="Text9" Rows=14 Cols=25></TextArea>
         <%else%>
            <TextArea Name="Text9" Rows=14 Cols=25><%=field.Value%></TextArea>
         <%end if%>
      </TD></TR></TABLE>

<CENTER><P>
<input type=button name=MoveFirst value="   |<   " onClick="MoveClick(1);">
<input type=button name=MovePrevious value="    <   " onClick="MoveClick(2);">
<INPUT Type=button  Name=absolute      Value=" <%=movecnt%> of <%=RS.RecordCount%> ">
<input type=button name=MoveNext value="   >    " onClick="MoveClick(3);">
<input type=button name=MoveLast value="   >|   " onClick="MoveClick(4);">
</P></CENTER>

<hr size="1" color="#000000">
<EM>This is a <%=dbms%> database.</EM>
<font size="+1">
<center><a href="default.asp">
Return Home</a></center></font>
</FORM>
</BODY>

<Script Language="JavaScript">
function MoveClick(option) {
   document.form1.action = "publishers.asp?dbms=<%=dbms%>&movecnt=<%=movecnt%>&direction=" + option;
   document.form1.submit();
}
</Script>
</HTML>